Acquire image SPIRAL

Edit Delete

Details

Name	Acquire image SPIRAL
Permalink	https://serialemscripts.nexperion.net/script/77
Category	Other Data Acquisition
Language	SerialEM Scripting
Description	Instead create a grid of points for a continuous carbon grid, typical for negative staining projects, this script only needs one point in the center of the square. The map of the whole grid is more than enough. It will then, after correcting for eucentricity and focus, go on to take spiral pictures by moving the stage. Focus will be corrected along the acquisition and well as beamcentering if requested.
Author	Francisco Javier Chichón

Version History

Version 1.1 (October 07, 2022; 111 download(s); SerialEM version ≥ 3.9)

Version 1.1

Download

Upload date	October 07, 2022
Download count	111
SerialEM version ≥	3.9

ScriptName ACQUIRE_IMAGES_SPIRAL
#  ============================================================
#  Istead create a grid of points for a continuous carbon grid,
#  typical for the negative staining project. 
#  This script only needs one point in the center of the square. 
#  It will then, after correcting for eucentricity and focus, 
#  go on to take spiral pictures by moving the stage. 
#  Focus will be corrected along the acquisition
# ============================================================
#  It will do the following after going to the point
#     1.- Eucenticity 1
#     2.- Focus autocenter BEAM (if desired)
#     3.- TAKE IMAGE
#     4.- MOVE $STEP in the apropiate direction
#     5.- TAKE IMAGE (UNTIL $FOCUS LIMIT, then do focus)
#     8.- CONTINUE UNTIL 3 images are black or you reach $MAX_VALUE
#     9.- NO change in target focus are prepared
# ============================================================
#
#  Script Created by Mikel Iceta and Javier Chichón
#                     September 2022
# ============================================================

echo ============================================================
DIR_LOCAL = 1 # If the arrays start at 1 this should start at 1
# EXECUTION PARAMETERS
MAX_VALUE = 20 # GET DE LIMIT OF THE SPIRAL. DIVIDE SQUARESIZE : NUMBER OF STEPS
STEP_INC = 3 # CHANGE (in microns) DISTANCE BETWEEN STEPS
THRESHOLD = 100 # Count Limits to stop. It meassueres the Average intensity
# to see if you are close to a border and stops the spiral loop.
# Values for determining the execution stop
STOP = 0 #Do not change (start counting)
DARK_LIMIT = 3 #images to acquire after a black image
DARK_COUNT = 0 # start counting black images (do not change)
#Focus Variables
# Num images to do Focus
FOCUS_LIMIT = 20 #
# Set to 0 to start with AutoFocus
FOCUStime = 0
# change if needed foru your purpose
SetTargetDefocus -0.8
#Start with Eucentricity
Eucentricity 1
#Do CenterBeam (0=NO BC) (1=CenterBeam) SetUp AutocenterBEAM
CB = 0 # if 1 it wull AutocenterBeam every FocusTime
# DEFINITION OF DIRECTION NAMES AND VALUES
V_DIRNAMES = {EAST SOUTH WEST NORTH}
New2DArray V_DIRS 0 4 2
V_DIRS[1][1] = $STEP_INC # East
V_DIRS[2][2] = -1 * $STEP_INC # South
V_DIRS[3][1] = -1 * $STEP_INC # West
V_DIRS[4][2] = $STEP_INC # North
# Between 1 and the max number of steps...
# For each level: advance(level times), rotate(90 degrees), advance(level times), rotate(90 degrees)
#   (go to)
#      >x------xv (turn 90º)
#                    |
#                    | (go to)
#                    |
#                 <x (turn 90º )
# Turning is simply marking that the next direction is another one.
Loop $MAX_VALUE STEP
   if $STOP == 1
      break
   Endif
   echo $V_DIRNAMES[$DIR_LOCAL]
   # FIRST ADVANCE:
   Loop $LEVEL STEP
      if $STOP == 1
         break
      Endif
      echo $STEP
      MoveStage $V_DIRS[$DIR_LOCAL][1] $V_DIRS[$DIR_LOCAL][2]
      CallFunction checkAndStop
   EndLoop
   # Turn:
   CallFunction rotate
   echo $V_DIRNAMES[$DIR_LOCAL]
   # 2nd level:
   Loop $LEVEL STEP
      if $STOP == 1
         break
      Endif
      echo $STEP
      MoveStage $V_DIRS[$DIR_LOCAL][1] $V_DIRS[$DIR_LOCAL][2]
      CallFunction checkAndStop
   EndLoop
   # Turn:
   CallFunction rotate
EndLoop
# @@@@@@@@@@@@@@@@@@@@@@@@
# FUNCTIONS
Function rotate
   if $DIR_LOCAL == 4
      DIR_LOCAL = 1
    Else
      DIR_LOCAL = $DIR_LOCAL + 1
   Endif
EndFunction
Function checkAndStop #TAKE THE IMAGE
   CallFunction FocusTime
   GoToLowDoseArea R
   Delay 10 sec #Depending on the microscope 10 is to be on a safety area
   #ACQUIRE THE IMAGE
   Record
   FOCUStime = $FOCUStime  + 1
   ReportMeanCounts
   if $RepVal1 < $THRESHOLD
      DARK_COUNT = $DARK_COUNT + 1
   Endif
   if $DARK_COUNT > $DARK_LIMIT
      echo Empty image limit reached. Stopping acquisition.
      STOP = 1
   Endif
EndFunction
Function FocusTime # SET FOCUS FRECUENCY
   if $FOCUStime >  $FOCUS_LIMIT
      FOCUStime  =  0
   Endif
   if $FOCUStime == 0
      GoToLowDoseArea F
      AutoFocus
      AutoFocus
      if CB == 1
         GoToLowDoseArea T
         Delay 1 sec
         AutoCenterBeam
         Delay 1 sec
         AutoCenterBeam
      endif
   Endif
EndFunction

Documentation

# Between 1 and the max number of steps...
# For each level: advance(level times), rotate(90 degrees), advance(level times), rotate(90 degrees)
# (go to)
# >x------xv (turn 90º)
# |
# | (go to)
# |
#

License

This code can be shared and adapted under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) License (https://creativecommons.org/licenses/by-nc-sa/4.0/)