Measure Sample Thickness (LM)

Edit Delete

Details

Name	Measure Sample Thickness (LM)
Permalink	https://serialemscripts.nexperion.net/script/68
Category	Single Particle
Language	SerialEM Scripting
Description	The LM version of "Measure Sample Thickness", in case the field of view at the lowest SA mag is not sufficient and montaging each grid square is not an option.
Author	Jan Rheinberger

Version History

Version 1.0 (February 18, 2021; 470 download(s); SerialEM version ≥ 3.9)

Version 1.0

Download

Upload date	February 18, 2021
Download count	470
SerialEM version ≥	3.9

# Optimized data acquisition workflow by sample thickness determination
# Rheinberger, Oostergetel, Resch, and Paulino, submitted for publication
# (C) Nexperion e.U. - Solutions for Electron Microscopy, 2020
# https://www.nexperion.net
# Requires SerialEM >= 3.9.0
# Last update February 09, 2021

ScriptName HFIT-MeasureThicknessLM
SuppressReports

EmptyString @=

# Parameters
# Also check microscope and camera parameter settings below!
SubareaRadius = 6
MFP = 485
CorrectionFactor = 35
MinimumThickness = 30
MaximumThickness = 50

# Check conditions
ReportStageXYZ
echo Checking conditions to acquire at $ReportedValue1:$ReportedValue2 ...
ReportIfNavOpen
if ( $ReportedValue1 == 0 )
   echo Navigator required for execution of script!
   Exit
EndIf
# TODO Check if file for maps is open!

# Set up camera parameters for Record
echo Setting up Search parameters ...
SetCameraArea S F
SetBinning S 4
SetExposure S 3 0
SetContinuous S 0
SetK2ReadMode S 1
SetDoseFracParams S 0

# Acquire images
echo Acquiring unfiltered image ...
Search
Copy A P
Save
NewMap

echo Acquiring filtered image ...
UpdateLowDoseParams S
SetSlitWidth 20
SetSlitIn 1
SetEnergyLoss -38
Search
AlignTo P 1
ReportAlignShift 
Copy A O

ShiftX = $ReportedValue1 / 8
ShiftY = $ReportedValue2 / 8
echo $ShiftX , $ShiftY

# Run hole finder
echo Running hole finder on unfiltered image ...
ReportOtherItem -1
NewStartIndex = ( $ReportedValue1 + 1 )
FindHoles P
MakeNavPointsAtHoles -1 0 9999999 -1 100
ClearHoleFinder
ReportOtherItem -1
NewLastIndex = $ReportedValue1

# Generate arrays for all newly added points
NumberOfPoints = ($NewLastIndex - $NewStartIndex + 1)
echo NumberOfPoints = $NumberOfPoints
NewArray ImageX 0 $NumberOfPoints
NewArray ImageY 0 $NumberOfPoints
NewArray MeanFiltered Y $NumberOfPoints
NewArray MeanUnfiltered Y $NumberOfPoints

# Get image coordinates for each point, exclude points in the very periphery that CircularSubareaMean can not be run on
MinX = $SubareaRadius
MinY = $SubareaRadius
ImageProperties P
MaxX = ($ReportedValue1 - $SubareaRadius - 1)
MaxY = ($ReportedValue2 - $SubareaRadius - 1)
DoLoop i $NewStartIndex $NewLastIndex
j = ($i - $NewStartIndex + 1)
ReportItemImageCoords $i P
If ( ( $ReportedValue3 == 1 ) AND ( $ReportedValue1 >= $MinX ) AND ( $ReportedValue2 >= $MinY ) AND ( $ReportedValue1 <= $MaxX ) AND ( $ReportedValue2 <= $MaxY ) )
   ImageX[$j] = $ReportedValue1
   ImageY[$j] = $ReportedValue2
EndIf
EndLoop

# Getting intensities from unfiltered image, invalid coordinates will be detected by CircularSubareaMean
echo Getting intensites from unfiltered image ...
Copy P A
DoLoop i $NewStartIndex $NewLastIndex
j = ($i - $NewStartIndex + 1)
if ( ( $ImageX[$j] > 0 ) AND ( $ImageY[$j] > 0 ) )
   CircularSubareaMean $ImageX[$j] $ImageY[$j] $SubareaRadius MeanUnfiltered[$j]
EndIf	
EndLoop

# Getting intensities from filtered image, invalid coordinates will be detected by CircularSubareaMean
echo Getting intensites from filtered image ...
Copy O A
DoLoop i $NewStartIndex $NewLastIndex
j = ($i - $NewStartIndex + 1)
if ( ( $ImageX[$j] > 0 ) AND ( $ImageY[$j] > 0 ) )
   ImageX2 = $ImageX[$j] - $ShiftX
   ImageY2 = $ImageY[$j] - $ShiftY
   #echo $imageX[$j], $ImageX2, $ImageY[$j], $ImageY2
   CircularSubareaMean $ImageX2 $ImageY2 $SubareaRadius MeanFiltered[$j]
EndIf	
EndLoop

# Calculate thickness for each hole and add as note
SuspendNavRedraw
DoLoop i $NewStartIndex $NewLastIndex
j = ($i - $NewStartIndex + 1)
if ( ( $ImageX[$j] > 0 ) AND ( $ImageY[$j] > 0 ) )
   Thickness = $MFP * LOG ( $MeanUnfiltered[$j] / $MeanFiltered[$j] ) - $CorrectionFactor
   Thickness = ROUND $Thickness 2
   #echo Calculated $Thickness nm for Navigator item $i ; $Thickness ; $MeanUnfiltered[$j] ; $MeanFiltered[$j] 
   ChangeItemNote $i $Thickness
   
   if ( $Thickness < $MinimumThickness )
      ChangeItemColor $i 4
      SetItemAcquire $i 0
    elseif ( $Thickness < $MaximumThickness )
      ChangeItemColor $i 1
      SetItemAcquire $i 1
    else 
      ChangeItemColor $i 2
      SetItemAcquire $i 0
   Endif
 Else
   ChangeItemNote $i
   #echo Navigator item $i coordinates not transformed
   SetItemAcquire $i 0
EndIf
EndLoop
SuspendNavRedraw 0

SetEnergyLoss 0
SetLowDoseMode 1

echo Done.

Related Scripts

The following scripts provide a similar or related functionality, but are not required to run this script:

License

This code can be shared and adapted under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) License (https://creativecommons.org/licenses/by-nc-sa/4.0/)