SPA data collection on JEOL CryoARM300

Edit Delete

Details

Name	SPA data collection on JEOL CryoARM300
Permalink	https://serialemscripts.nexperion.net/script/58
Category	Single Particle
Language	SerialEM Scripting
Description	This script allows automated data collection on a JEOL CryoARM
Author	Marcus Fislage
Literature reference	https://journals.iucr.org/m/issues/2020/04/00/pw5013/index.html
Website link	http://www.becm.be

Version History

Version 2

Download

This script requires additional scripts to be run – please refer to the Required Scripts section below.

Upload date	April 02, 2021
Download count	434
SerialEM version ≥	3.8

MacroName CollectSPA
###################################
#
# Script to acquire SPA data
#
# M.Fislage & R. Efremov Jan 2021
#   
# STATUS: functional
#
###################################

Call Parameters
if $debug_tur == 0 
   SuppressReports
endif

# Check if gun to be flashed, HWDark Reference to be made and dewars to be filled or being filled
CallFunction MyFunctions::WaitForRefillingJ
LongOperation FF $FlashInterval
UpdateHWDarkRef $DarkRefInterval

# SET LOCAL TIMER

IsVariableDefined NN
if  $reportedValue1 == 1
   NN := $NN + 1
   echo Here is NN $NN
 else
   NN := 1
   echo Created NN $NN
endif

#Define counter for low intensity images
IsVariableDefined LowCount
if  $reportedValue1 == 0
   LowCount := 0
endif

# Realign to Item with special considerations for cryoARM beam sizes
GoToLowDoseArea V
# realign with accuracy of 1 um, trying 2 iterations to fit the stage and leave IS for the best fit
ForceCenterRealign # uncomment if alignmnent is poor
ResetClock
#RealignToNavItem 1 0 1 2 0
RealignToNavItem 1 0 1.5 1 0

RelaxStage 0.025
Delay $STAGE_STAB_TIME sec

# CHECK  CENTER BEAM TIMER
IsVariableDefined BeamCenterTimeOld
if $reportedValue1 == 0
   BeamCenterTimeOld := 0
endif
ReportMinuteTime BeamCenterTime
if ( $BeamCenterTime - $BeamCenterTimeOld ) > $BeamCentTimeInterval
   CENTER_FLAG = 1
 else
   CENTER_FLAG = 0
endif
ReportClock
echo TIME: time for hole centering $reportedValue1 sec.
ResetClock

# FOCUS
# check position of previous focus
ReportStageXYZ
stX = $reportedValue1
stY = $reportedValue2
IsVariableDefined FocX
if  $reportedValue1 == 0          # no focusing has been done yet 
   FocX := $stX
   FocY := $stY
   DoFoc = 1
 else
   distF =  SQRT ( POWER ( (  $stX -  $FocX ) 2 ) + POWER ( ( $stY -  $FocY ) 2 ) )
   echo Distance from the last focus position is $distF
   if   $distF > $FocusDistance
      FocX := $stX
      FocY := $stY
      DoFoc = 1
    else
      DoFoc = 0
   endif
endif

# Focus or set focus value only
CallFunction MyFunctions::CycleDefocusTarget
if  $DoFoc == 1
   GoToLowDoseArea F
   FocusChangeLimits  -50 50
   AutoFocus 
   ReportAutofocus
   FocusError = $reportedValue2
   ReportMeanCounts
   FocusCounts =  $reportedValue1
   if (  $FocusError != 0 ) or ( $FocusCounts < 200 )
      echo WARNING: FOCUS LIKELY FAILED: FocusError $FocusError and FocusCounts  $FocusCounts
      echo RESET DEFOCUS TO 0
      SetDefocus 0
      FocX :=
   endif                
   # check if focus is not too far from absolute focus, if so, moves Z height to be close to absolute focus
   # Current cutoff  5um and the offset is calculated  relative to -1 um defocus
   ReportDefocus
   CurDef := $reportedValue1
   ReportTargetDefocus
   OldTarDef := $reportedValue1
   RelDef = -1
   StShift = $CurDef - $RelDef
   if ( ABS $StShift ) > 5.0
      if ( ABS $StShift ) < 50.0
         echo WARNING: LARGE DEFOCUS  GRID IS LIKELY BENT moving Z  stage by $StShift
         MoveStage 0 0 $StShift
         UpdateGroupZ
         Delay 10 sec # stage settling
         RealignToNavItem 1 0 0.5 1 0
         Autofocus
         ReportDefocus
         CurDef := $reportedValue1
       else
         echo WARNING:THE FOCUSING LIKELY FAILED - DO NOT MOVE THE STAGE Z HEIGHT, SET FOC 0 and FORCE FOCUSING NEXT HOLE
         SetDefocus 0
         FocX :=
      endif              
   endif
 else
   if  $CENTER_FLAG == 1
      GoToLowDoseArea T 
    else
      GoToLowDoseArea R
   endif
   ReportTargetDefocus
   NewDef = $CurDef - $OldTarDef + $reportedValue1
   echo Do not do focusing set defocus to $NewDef 
   SetDefocus  $NewDef
endif

ReportClock
echo TIME: time for FOCUSING $reportedValue1 sec.
ResetClock

# CENTER BEAM 
if  $CENTER_FLAG == 1
   echo Centering beam ...
   CallFunction MyFunctions::CenterBeam Beam
   ReportMinuteTime BeamCenterTimeOld
   ReportBeamShift    
   echo NEW BEAM POSITION $reportedValue1 $reportedValue2
endif

# Take the shot

ReportClock
echo TIME: time for BEAM CENTERING $reportedValue1 sec.
ResetClock

ReportLowDose
if $reportedValue2 != 3 
   GoToLowDoseArea R
endif

CallFunction MyFunctions::MultiShot
CallFunction MyFunctions::Nobeam   ###Test email for lost beam
ReportClock
echo TIME: time for IMAGE RECORDING $reportedValue1 sec.
EndMacro

Required Scripts

The following scripts are required to run this script, either because the are called directly or they provide functions:

Documentation

Be in low dose mode
Have acquisition points activated in the navigator file and run through Navigator menue --> Acquire at Items

Version2 is significantly faster and allows easy use of multihole collection

License

This code can be shared and adapted under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) License (https://creativecommons.org/licenses/by-nc-sa/4.0/)