Jensen lab FISE Calibrations

Edit Delete

Details

Name	Jensen lab FISE Calibrations
Permalink	https://serialemscripts.nexperion.net/script/54
Category	Tomography
Language	SerialEM Scripting
Description	This script is used to acquire pre-calibration shifts in X and Y prior to FISE tilt-series acquisition using the Search parameter in serialEM. The script was tested with a Search parameter set to a magnification with a pixel size near 10 Å.
Author	Georges Chreifi
Website link	https://github.com/chreifi/FISE

Version History

Version 1 (May 19, 2020; 312 download(s); SerialEM version ≥ 3.8)

Version 1

Download

This script requires additional scripts to be run – please refer to the Required Scripts section below.

Upload date	May 19, 2020
Download count	312
SerialEM version ≥	3.8

ScriptName GetCalibrations

# Files named 'ArrayTilt_angles.txt' and 'ArrayTilt_defoci.txt' must be in the working directory for this script to work correclty!

Echo Collecting a calibration tilt-series for map # $CurrentMap

#### SETTINGS #########
useSmallArea = 1 # Enter 1 to use a smaller camera area for improved accuracy (K3 only).
PosCalib = 0.1 # Positive tilt angle below which no image shift calibration will be acquired
NegCalib = -0.1 # Negative tilt angle above which no image shift calibration will be acquired
# Ex: Setting PosCalib = 45 and NegCalib = -30 will apply image shifts to tilts equal to or higher than +45, or lower than -30.
#######################
## EXPOSURE TIME ADJUSTMENT
SearchExposure := 0.05 # Initial exposure time for Search
targetmean := 100 # Target mean count value for a good search image
#######################

ResetClock
If $useSmallArea == 1
   SetCameraArea 5 1000 4760 0 4092
Endif
Search
ElectronStats A
currentmean = $reportedValue3
NewExp := $SearchExposure * $targetmean / $currentmean
Echo Setting Search exposure to $NewExp
SetExposure 5 $NewExp

TotalTilts = ($MaxAngle * 2 / $TiltIncr) + 1
### Pre-steps
Search
ElectronStats A
Copy A P
Copy A T
ReportSpecimenShift
deltaX0 = $reportedValue1
deltaY0 = $reportedValue2

OpenTextFile ANGLES R 0 ArrayTilt_angles.txt
OpenTextFile DEFOCI R 0 ArrayTilt_defoci.txt
OpenTextFile ARRAY O 0 ArrayTilt_output.txt
OpenTextFile LOG O 0 ArrayTilt_log_$CurrentMap.txt

Loop $TotalTilts
   ReadLineToString ANGLES TiltAngle
   ReadLineToString DEFOCI Defocus
   TiltTo $TiltAngle
   ReportTiltAngle 
   check = $reportedValue1
   ActualExp = 1 / ( COS ( $check ) )  * $ExpTime
   
   If $check >= $PosCalib OR $reportedValue1 <= $NegCalib 
      Search
      If $check > 0
         AlignTo P
         Copy A P
      EndIf
      If $check < 0
         AlignTo T
         Copy A T
      Endif 
      ReportSpecimenShift
      deltaX1 = $reportedValue1
      deltaY1 = $reportedValue2
      
      deltaX = $deltaX1 - $deltaX0
      deltaY = $deltaY1 - $deltaY0
      
      WriteLineToFile ARRAY $TiltAngle $ActualExp $Settling $Defocus $deltaX $deltaY
      WriteLineToFile LOG $TiltAngle $ActualExp $Settling $Defocus $deltaX $deltaY
      
      deltaX = 0 - $deltaX
      deltaY = 0 - $deltaY
      ImageShiftByMicrons $deltaX $deltaY
    Else
      WriteLineToFile ARRAY $TiltAngle $ActualExp $Settling $Defocus 0 0
      WriteLineToFile LOG $TiltAngle $ActualExp $Settling $Defocus 0 0
   Endif 
EndLoop

TiltTo 0

CloseTextFile ARRAY

ReadTextFile ArrayTmp ArrayTilt_output.txt
ArrayTilt := $ArrayTmp
Echo $ArrayTilt
ReportClock
Echo Finished acquiring calibration tilt series for map # $CurrentMap!

Required Scripts

The following scripts are required to run this script, either because the are called directly or they provide functions:

Jensen lab FISE

Related Scripts

The following scripts provide a similar or related functionality, but are not required to run this script:

Measure Eucentric Height Alternative

Documentation

This script is called by the Jensen lab FISE script.

Make sure to do the following before runnign the FISE script:
1) Insert both scripts into SerialEM.
2) Place the files 'ArrayTilt_angles.txt' and 'ArrayTilt_defoci.txt' in the working directory.

License

This code can be shared and adapted under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) License (https://creativecommons.org/licenses/by-nc-sa/4.0/)