Save Microscope State

Edit Delete

Details

Name	Save Microscope State
Permalink	https://serialemscripts.nexperion.net/script/31
Category	High-Level Functions
Language	SerialEM Scripting
Description	Saves the current state of the microscope (illumination, image shift, focus, mag, stage position) for later restoration using the "Restore Microscope State" script
Author	Guenter Resch
Website link	https://www.nexperion.net

Version History

Version 1.0 (February 26, 2018; 546 download(s); SerialEM version ≥ 3.6)

Version 1.0

Download

This script requires additional scripts to be run – please refer to the Required Scripts section below.

Upload date	February 26, 2018
Download count	546
SerialEM version ≥	3.6

# (C) Nexperion e.U. - Solutions for Electron Microscopy 2018
# https://www.nexperion.net
# Last update February 26, 2018
# Requires SerialEM >= 3.6.x

# Parameters not covered in this version of the script include: JEOL Alpha, diffraction/imaging mode, piezo drive, filter, camera settings (inserted/retracted)

ScriptName SaveScopeState
SuppressReports

echo
echo SAVING MICROSCOPE STATE:
IsVariableDefined _N3SFlag
if ( $ReportedValue1 == 1)
   YesNoBox Do you want to overwrite the currently saved microscope state?
   If ( $ReportedValue1 != 1) 
      echo Cancelled.
      echo
      Exit
   EndIf
EndIf

echo Saving illumination ...
ReportProbeMode
_N3SProbeMode := $ReportedValue1
ReportSpotSize
_N3SSpotSize := $ReportedValue1
ReportPercentC2
_N3SPercentC2 := $ReportedValue1
ReportBeamShift
_N3SBeamShiftX := $ReportedValue1
_N3SBeamShiftY := $ReportedValue2
ReportBeamTilt
_N3SBeamTiltX := $ReportedValue1
_N3SBeamTiltY := $ReportedValue2

echo Saving image shift ...
ReportImageShift
_N3SImageShiftX := $ReportedValue1
_N3SImageShiftY := $ReportedValue2

echo Saving focus ...
ReportAbsoluteFocus
_N3SAbsoluteFocus := $ReportedValue1

echo Saving magnification ...
ReportMag
_N3SMag := $ReportedValue1

echo Saving stage position ...
ReportStageXYZ
_N3SStageX := $ReportedValue1
_N3SStageY := $ReportedValue2
_N3SStageZ := $ReportedValue3
ReportTiltAngle
_N3SStageA := $ReportedValue1

_N3SFlag := 1

echo DONE.
echo

Required Scripts

The following scripts are required to run this script, either because the are called directly or they provide functions:

Restore Microscope State

Documentation

The state of the microscope is saved to persistent variables that live as long as a SerialEM session (regular variables only live as long as the script is running).

Various microscope parameters are not implemented yet, see comments in script.

License

This code can be shared and adapted under the Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International (CC BY-NC-SA 4.0) License (https://creativecommons.org/licenses/by-nc-sa/4.0/)